#include <Sleep.h>
#include <NewSoftSerial.h>

#define DEBUG 0

// rx is not being used, so that's a dummy number.
NewSoftSerial XBSerial = NewSoftSerial(5, 4);

int CTSpin = 7;
int XBpin  = 6;

static int CTS=0;                        // value of XBee CTS digital pin
static byte wdt_count = 0;               // watchdog timer counter
static unsigned long tBusyPrev=0;        // busy time of each transmission
volatile boolean wdt_expired=0;          // 1 when watchdog timer expired.

// Interrupt Service Routine that will be executed when the Watchdog Timer expires.
ISR(WDT_vect) {
  wdt_expired=1;
}

void setup_watchdog(int ii) {
//
// parameter:
// 0=16ms, 1=32ms,2=64ms,3=128ms,4=250ms,5=500ms
// 6=1 sec,7=2 sec, 8=4 sec, 9= 8sec
//

  byte bb;
  int ww;
  if (ii > 9 ) ii=9;
  bb=ii & 7;
  if (ii > 7) bb|= (1<<5);
  bb|= (1<<WDCE);
  ww=bb;

  MCUSR &= ~(1<<WDRF);
  // start timed sequence
  WDTCSR |= (1<<WDCE) | (1<<WDE);
  // set new watchdog timeout value
  WDTCSR = bb;
  WDTCSR |= _BV(WDIE);
}

static void Send (int Motion) {

  unsigned long tXB1;    // millis XBee was woken up
  unsigned long tXB0;    // millis XBee was put back to sleep
  unsigned long tBusy0;  // start active time
  unsigned long tBusy1;  // end active time

  tBusy0=millis();
  
  CTS = HIGH;
  tXB0=millis();         

  // wake up Xbee
  digitalWrite(XBpin,LOW);

  // wait for CTS to become LOW
  do 
  {
    CTS=digitalRead(CTSpin);
  } 
  while (CTS != LOW);
  tXB1=millis();
  // wait 3 msec otherwise data will be received all messed up
  delay(3);

  // send motion, 'time' and some timing values for monitoring
  XBSerial.print(Motion);
  XBSerial.print(" ");
  XBSerial.print(millis());
  XBSerial.print(" ");
  XBSerial.print(tBusyPrev);
  XBSerial.print(" ");
  XBSerial.println(tXB1-tXB0);

  // wait again for XBee to finish transmission
  delay(4);

  // switch off XBee
  digitalWrite(XBpin,HIGH);    
  delay(3);  // todo: test if this one can be removed
  
  // reset watchdog timer count (for Heartbeat)
  wdt_count = 0;
  
  // how long did all this take?
  // remember this, will be sent at next transmission.
  tBusy1=millis();  
  tBusyPrev = tBusy1-tBusy0;
}

void setup(void)
{
  // setup XBee
  pinMode(CTSpin,INPUT);  
  pinMode(XBpin,OUTPUT);  

  digitalWrite(XBpin,LOW);    // wrong? PAGE 73
  digitalWrite(CTSpin,LOW);   // really necessary?
  delay(10);

  XBSerial.begin(9600);
  
  // give XBee some time to join PAN
  delay(5000);

  // let the world know we're here
  XBSerial.println("[Motionv2]");
  
  delay(20);
  digitalWrite(XBpin, HIGH); 
}

void loop(void)
{
  // power down mode and wait for next interrupt,
  // being either motion or watchdog.
  wdt_expired=0;
  setup_watchdog(9);  // 8 seconds.
  Sleep.powerDownAndWakeupExternalEvent(1, RISING);     // trigger on PIR going high
   
  if (wdt_expired==1){
    wdt_expired=0;
    wdt_count++;

    // Sending a heatbeat (sometimes)
    if (wdt_count >= 4) {
      // since watchdog expired, there's no motion...
      Send(0);
    }
  }
  else
  {
    // Motion!
    Send(1);

    // Go to sleep WITHOUT activating IRQ,
    // wake up after some time and resume operation *with*.
    // This is to avoid multiple motion notifications
    // being sent in a very short time, caused by
    // the PIR output jumping high and low all the time,
    // call it debouncing :-)

    setup_watchdog(9);
    Sleep.powerDown();

    // after waking up again,
    // enter powerdown with IRQ again.
  }
}